# RemotePlayerView —— ClientVS22 的远端 PC 表现层。
#
# 远端 PC 与本地玩家共用 PlayerView 的 race / GR2 / MSA 装载，但装备来源
# 必须是 awPart[CHR_EQUIPPART_ARMOR..HAIR]，不能读取本地 get_equipment()。
extends "res://ui/player_view.gd"

const EquipModel = preload("res://ui/equip_model.gd")

var remote_equip: Node
var _remote_parts: Array = []

func build_remote(assets_root: String, race: int, parts: Array, item_list: RefCounted,
		proto: Node = null, pump := Callable()) -> bool:
	if not build(assets_root, race, pump):
		return false
	_remote_parts = parts.duplicate()
	while _remote_parts.size() < 4:
		_remote_parts.append(0)
	if _remote_parts.size() > 4:
		_remote_parts = _remote_parts.slice(0, 4)
	remote_equip = EquipModel.new()
	remote_equip.name = "RemoteEquipModel"
	add_child(remote_equip)
	remote_equip.setup_remote(item_list, func() -> Node: return self, assets_root, race,
			_remote_parts, proto)
	return true

# net_world 按 NetworkActorManager.cpp:473 的顺序调用这四个字段。
func set_armor(vnum: int) -> void:
	_set_remote_part(EquipModel.PART_ARMOR, vnum)

func set_weapon(vnum: int) -> void:
	_set_remote_part(EquipModel.PART_WEAPON, vnum)

func set_head(vnum: int) -> void:
	_set_remote_part(EquipModel.PART_HEAD, vnum)

func set_hair(vnum: int) -> void:
	_set_remote_part(EquipModel.PART_HAIR, vnum)

func _set_remote_part(index: int, vnum: int) -> void:
	while _remote_parts.size() <= index:
		_remote_parts.append(0)
	_remote_parts[index] = vnum
	if remote_equip:
		remote_equip._set_remote_part(index, vnum)
		remote_equip.refresh()