# weapon_attach_test —— 武器挂点按种族 + 左右手（真 PlayerView + 真 gr2）。
#   godot --headless --path project --script weapon_attach_test.gd
#
# 参考端 playersettingmodule.py RegisterAttachingBoneName：
#   warrior  PART_WEAPON=equip_right_hand                          (661)
#   assassin PART_WEAPON=equip_right  PART_WEAPON_LEFT=equip_left  (873-874)
#   sura     PART_WEAPON=equip_right                               (999)
#   shaman   PART_WEAPON=equip_right  PART_WEAPON_LEFT=equip_left  (1190-1191)
# ActorInstanceAttach.cpp AttachWeapon：GetAttachingBoneName 失败（该职业没登记左手）就不挂。
# PlayerView 的 shield_gr2 槽 = PART_WEAPON_LEFT（参考端没有盾牌挂件）。
extends SceneTree

const PlayerView = preload("res://ui/player_view.gd")

const RIGHT_BONE := ["equip_right_hand", "equip_right", "equip_right", "equip_right"]
const LEFT_BONE := ["", "equip_left", "", "equip_left"]
const MAX_GRIP_M := 0.10

var _fail := 0
func _ck(c: bool, m: String) -> void:
	if not c:
		_fail += 1
		printerr("FAIL: " + m)

func _init() -> void:
	await _run()
	if _fail == 0:
		print("PASS: weapon_attach_test (race attaching bones + left/right hand)")
		quit(0)
	else:
		printerr("%d check(s) failed" % _fail)
		quit(1)

func _run() -> void:
	if not ClassDB.class_exists("Metin2Model"):
		print("  (skip: no Metin2Model extension)")
		return
	var assets := AssetRoot.path()
	var weapon_dir := assets.path_join("item/ymir work/item/weapon")
	var sword := weapon_dir.path_join("00010.gr2")
	var dagger := weapon_dir.path_join("04000.gr2")
	if not FileAccess.file_exists(sword) or not FileAccess.file_exists(dagger):
		print("  (skip: weapon gr2 assets missing)")
		return
	await process_frame
	for race in 8:
		var job := race & 3
		var pv = PlayerView.new()
		get_root().add_child(pv)
		if not pv.build(assets, race):
			print("  (skip race %d: body assets missing)" % race)
			pv.free()
			continue
		pv.set("weapon_gr2", sword)
		pv.set("shield_gr2", dagger)
		for i in 3:
			await process_frame
		var right := pv.model.get_node_or_null("Weapon") as Node3D
		_ck(right != null, "race %d: right-hand weapon attached (%s)" % [race, RIGHT_BONE[job]])
		if right:
			_ck(_near(pv, right, RIGHT_BONE[job]), "race %d: weapon sits on %s" % [race, RIGHT_BONE[job]])
		var left := pv.model.get_node_or_null("Shield") as Node3D
		if LEFT_BONE[job] == "":
			_ck(left == null, "race %d: no PART_WEAPON_LEFT bone registered -> nothing on left hand" % race)
		else:
			_ck(left != null, "race %d: left-hand weapon attached (%s)" % [race, LEFT_BONE[job]])
			if left:
				_ck(_near(pv, left, LEFT_BONE[job]), "race %d: left weapon sits on %s" % [race, LEFT_BONE[job]])
		pv.queue_free()
		await process_frame

func _near(pv: Node, node: Node3D, bone: String) -> bool:
	var pose: Dictionary = pv.anim.call("get_effect_bone_pose", bone)
	if pose.is_empty():
		printerr("  bone %s has no pose" % bone)
		return false
	var hand: Vector3 = (pv.model as Node3D).global_transform * (pose["transform"] as Transform3D).origin
	var d := node.global_position.distance_to(hand)
	if d > MAX_GRIP_M:
		printerr("  %s is %.3f m from %s" % [node.name, d, bone])
	return d <= MAX_GRIP_M