cmake_minimum_required(VERSION 3.20)
project(metin2_native CXX C)

include(CTest)

set(CMAKE_CXX_STANDARD 20)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_C_STANDARD 17)
set(CMAKE_EXPORT_COMPILE_COMMANDS ON)

if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
    set(CMAKE_BUILD_TYPE Debug CACHE STRING "" FORCE)
endif()

option(MT_BUILD_TOOLS "Build libgr2 validation tools" OFF)
option(MT_BUILD_NET_TOOLS "Build the host-only classic protocol probe" OFF)
option(MT_BUILD_PORT "Build the 40250 port and its tests" ON)
option(MT_BUILD_NATIVE_RENDER "Build the SDL3 and Vulkan client" OFF)

add_subdirectory(libgr2)
add_subdirectory(formats)
add_subdirectory(extension/third_party)
add_subdirectory(extension/src/codepage)
if(MT_BUILD_PORT OR MT_BUILD_NATIVE_RENDER)
    add_subdirectory(extension/src/port)
endif()

if(MT_BUILD_TOOLS)
    add_subdirectory(tools)
endif()

# The protocol probe remains useful on the archived server's FreeBSD host.
if(MT_BUILD_NET_TOOLS)
    add_library(mtnet_host STATIC
        extension/src/net/text_codec.cpp
        extension/src/net/secure_cipher.cpp
        extension/src/net/net_stream.cpp
        extension/src/net/entity_store.cpp
        extension/src/net/mark_image.cpp
        extension/src/net/classic/classic_stream.cpp
        extension/src/net/classic/classic_parser.cpp
        extension/src/net/classic/classic_session.cpp
        extension/src/net/classic/classic_cipher.cpp
    )
    target_include_directories(mtnet_host PUBLIC extension/src/net)
    target_link_libraries(mtnet_host PUBLIC mt3p::sodium mt3p::minilzo mt3p::cryptopp mt_codepage)
    target_compile_features(mtnet_host PUBLIC cxx_std_20)

    add_executable(net_classic_e2e_host extension/tools/net_classic_e2e.cpp)
    target_link_libraries(net_classic_e2e_host PRIVATE mtnet_host)
endif()

if(MT_BUILD_NATIVE_RENDER)
    add_subdirectory(native_render)
endif()