193 lines
7.3 KiB
GDScript
193 lines
7.3 KiB
GDScript
# char_create_delete_test —— 选人页建号 / 删号 UI + M2Client 封包对接 headless 自检。
|
|
# godot --headless --path project --script char_create_delete_test.gd
|
|
# 用假 client 记录 create_character / delete_character 调用；不需要资产 / 服务器。
|
|
extends SceneTree
|
|
|
|
const CharSelectScreen = preload("res://ui/char_select_screen.gd")
|
|
|
|
class FakeClient extends Node:
|
|
signal char_created(slot: int)
|
|
signal char_create_failed(reason_type: int)
|
|
signal char_deleted(slot: int)
|
|
signal char_delete_failed()
|
|
var creates: Array = []
|
|
var deletes: Array = []
|
|
var renames: Array = []
|
|
var selected_empires: Array = []
|
|
var slot_count := 4
|
|
func get_slot_count() -> int: return slot_count
|
|
var empire := 1
|
|
func get_empire() -> int: return empire
|
|
func select_empire(value: int) -> bool:
|
|
selected_empires.append(value)
|
|
empire = value
|
|
return true
|
|
func has_method_shim() -> void: pass
|
|
func create_character(slot, name, job, shape, con, i, s, d) -> bool:
|
|
creates.append({"slot": slot, "name": name, "job": job, "shape": shape,
|
|
"con": con, "int": i, "str": s, "dex": d})
|
|
return true
|
|
func delete_character(slot, code) -> bool:
|
|
deletes.append({"slot": slot, "code": code})
|
|
return true
|
|
func change_name(slot, name) -> bool:
|
|
renames.append({"slot": slot, "name": name})
|
|
return true
|
|
|
|
var _fail := 0
|
|
func _ck(c: bool, m: String) -> void:
|
|
if not c:
|
|
_fail += 1
|
|
printerr("FAIL: " + m)
|
|
|
|
func _init() -> void:
|
|
await _run()
|
|
if _fail == 0:
|
|
print("PASS: char_create_delete_test")
|
|
quit(0)
|
|
else:
|
|
printerr("%d check(s) failed" % _fail)
|
|
quit(1)
|
|
|
|
# 有弹窗时只在弹窗子树里找，避免撞到背后面板上的同名按钮
|
|
func _scope(s: Node) -> Node:
|
|
var d = s._dialog_node()
|
|
return d if d != null else s
|
|
|
|
func _find(node: Node, cls: String, pred := Callable()) -> Node:
|
|
for n in node.find_children("*", cls, true, false):
|
|
if not pred.is_valid() or pred.call(n):
|
|
return n
|
|
return null
|
|
|
|
func _btn(root: Node, text: String) -> Button:
|
|
return _find(_scope(root), "Button", func(b): return String(b.text) == text)
|
|
|
|
func _run() -> void:
|
|
var fc := FakeClient.new()
|
|
get_root().add_child(fc)
|
|
|
|
var s: Control = CharSelectScreen.new()
|
|
s.name = "CharSelect"
|
|
get_root().add_child(s)
|
|
# 1 个已有角色（槽 0），slot_count=4 -> 补 3 个空槽
|
|
s.setup(fc, "", [{"index": 0, "name": "Hero", "job": 0, "level": 30,
|
|
"guild_id": 0, "guild_name": "", "play_minutes": 90,
|
|
"st": 10, "ht": 9, "dx": 8, "iq": 7}])
|
|
# app_flow 平时做的接线（这里手接）
|
|
s.create_requested.connect(func(spec: Dictionary):
|
|
fc.create_character(spec["slot"], spec["name"], spec["job"], spec["shape"],
|
|
spec["con"], spec["int"], spec["str"], spec["dex"]))
|
|
s.delete_requested.connect(func(idx: int, code: String): fc.delete_character(idx, code))
|
|
s.change_name_requested.connect(func(idx: int, name: String): fc.change_name(idx, name))
|
|
await process_frame
|
|
|
|
_ck(s._chars.size() == 4, "padded to 4 slots, got %d" % s._chars.size())
|
|
_ck(s._first_occupied() == 0, "first occupied slot = 0")
|
|
|
|
# --- 建号：走到空槽 -> 开创建弹窗 -> 填名 -> 点“创建” ---
|
|
s._select(1) # 槽 1（空）
|
|
await process_frame
|
|
s._open_create_dialog()
|
|
await process_frame
|
|
var name_edit := _find(s, "LineEdit", func(n): return n.name == "Name") as LineEdit
|
|
_ck(name_edit != null, "create dialog has Name field")
|
|
var job_opt := _find(s, "OptionButton", func(n): return n.name == "Job") as OptionButton
|
|
_ck(job_opt != null and job_opt.get_selected_id() == 1, "job defaults to slot index (assassin)")
|
|
name_edit.text = "Newbie"
|
|
var ok := _btn(s, "创建")
|
|
_ck(ok != null, "create dialog has 创建 button")
|
|
ok.pressed.emit()
|
|
await process_frame
|
|
_ck(fc.creates.size() == 1, "create_character called once")
|
|
if fc.creates.size() == 1:
|
|
var c: Dictionary = fc.creates[0]
|
|
_ck(c["slot"] == 1 and c["name"] == "Newbie" and c["job"] == 1, "create args: slot/name/job")
|
|
# assassin 基础四维 con3 int3 str4 dex6
|
|
_ck(c["con"] == 3 and c["int"] == 3 and c["str"] == 4 and c["dex"] == 6,
|
|
"create sends assassin base stats (got %s)" % c)
|
|
|
|
# 太短的名字不发
|
|
s._open_create_dialog()
|
|
await process_frame
|
|
(_find(s, "LineEdit", func(n): return n.name == "Name") as LineEdit).text = "x"
|
|
_btn(s, "创建").pressed.emit()
|
|
await process_frame
|
|
_ck(fc.creates.size() == 1, "short name rejected client-side")
|
|
|
|
# 服务器回 char_created -> 弹窗关闭
|
|
fc.char_created.emit(1)
|
|
# app_flow 正常会转发；这里直接调
|
|
s.on_char_created(1)
|
|
await process_frame
|
|
_ck(s._dialog_node() == null, "dialog closed on char_created")
|
|
|
|
# --- 删号：选已有角色 -> 删除弹窗 -> 输码 -> 点“删除” ---
|
|
s._select(0)
|
|
await process_frame
|
|
s._open_delete_dialog()
|
|
await process_frame
|
|
var code := _find(s, "LineEdit", func(n): return n.name == "Code") as LineEdit
|
|
_ck(code != null and code.secret, "delete dialog has secret Code field")
|
|
code.text = "1234567"
|
|
_btn(s, "删除").pressed.emit()
|
|
await process_frame
|
|
_ck(fc.deletes.size() == 1 and fc.deletes[0]["slot"] == 0 and fc.deletes[0]["code"] == "1234567",
|
|
"delete_character(0, '1234567')")
|
|
|
|
# 服务器拒绝 -> 清空输入框
|
|
s.on_char_delete_failed()
|
|
await process_frame
|
|
var code2 := _find(s, "LineEdit", func(n): return n.name == "Code") as LineEdit
|
|
_ck(code2 == null or code2.text == "", "delete code cleared on failure")
|
|
|
|
# set_chars 保留当前选中槽
|
|
s._select(0)
|
|
s.set_chars([{"index": 0, "name": "Hero", "job": 0, "level": 31}])
|
|
await process_frame
|
|
_ck(s._slot_index() == 0, "set_chars keeps selection on slot 0")
|
|
|
|
# --- 强制改名：40250 在角色槽位标记 change_name 时，点击开始先改名 ---
|
|
s.set_chars([{"index": 0, "id": 42, "name": "Hero", "job": 0, "level": 31,
|
|
"change_name": true}])
|
|
await process_frame
|
|
s._select(0)
|
|
s._do_start()
|
|
await process_frame
|
|
var rename_edit := _find(s, "LineEdit", func(n): return n.name == "Name") as LineEdit
|
|
_ck(rename_edit != null, "forced rename dialog has Name field")
|
|
rename_edit.text = "x"
|
|
_btn(s, "改名").pressed.emit()
|
|
await process_frame
|
|
_ck(fc.renames.is_empty(), "short rename rejected client-side")
|
|
rename_edit.text = "Renamed"
|
|
_btn(s, "改名").pressed.emit()
|
|
await process_frame
|
|
_ck(fc.renames.size() == 1 and fc.renames[0]["slot"] == 0 and fc.renames[0]["name"] == "Renamed",
|
|
"change_name(0, 'Renamed')")
|
|
s.on_char_name_changed(42, "Renamed")
|
|
await process_frame
|
|
_ck(s._dialog_node() == null and not bool(s._cur().get("change_name", true)),
|
|
"rename success clears forced-rename state")
|
|
|
|
# --- 新账号：必须先选择阵营，成功后才恢复建号/进入按钮 ---
|
|
fc.empire = 0
|
|
var es: Control = CharSelectScreen.new()
|
|
get_root().add_child(es)
|
|
es.setup(fc, "", [{"index": 0, "name": "Hero", "job": 0, "level": 30}])
|
|
await process_frame
|
|
var empire_button := _find(es, "Button", func(n): return String(n.text) == "神獸王國") as Button
|
|
_ck(empire_button != null, "empire-required page shows empire choice")
|
|
_ck(_find(es, "Button", func(n): return String(n.text) == "开始" and n.disabled) != null,
|
|
"start disabled until empire is selected")
|
|
if empire_button:
|
|
empire_button.pressed.emit()
|
|
await process_frame
|
|
_ck(fc.selected_empires.size() == 1 and fc.selected_empires[0] == 1,
|
|
"empire button sends select_empire(1)")
|
|
_ck(_find(es, "Button", func(n): return String(n.text) == "开始" and not n.disabled) != null,
|
|
"start re-enabled after empire selection")
|
|
|
|
s.queue_free()
|
|
es.queue_free()
|